Parametric DCL Source code.

parametric : dialog { // Begin dialog

  label = "Parametric model";

  key = "title";

  : row { //  Upper row

    : column { // Begin left column

      : radio_row {

        : radio_button { // Solid model selection

        label = "Solid";

        key = "sol";

        value = "1";

        }

        : radio_button { // Surface model selection

        label = "Surface";

        key = "sur";

        value = "0";

        }

      }

      : boxed_column { // Parameter edition

      label = "Parameters";

        : edit_box {

        edit_width = 15;

        label = "DimX";

        key = "dx";

        value = "100.00";

        }

        : edit_box {

        edit_width = 15;

        label = "DimY";

        key = "dy";

        value = "100.00";

        }

        : edit_box {

        edit_width = 15;

        label = "FilletRadius";

        key = "ra";

        value = "25.00";

        }

        : edit_box {

        edit_width = 15;

        label = "CenterRadius";

        key = "rc";

        value = "50.00";

        }

        errtile;   // Warning messages

      }

    ok_cancel; // Ok and Cancel buttons

    

    }// End left column

    : column { // Begin right column

      : image { // Image

      key = "img";

      width = 35;

      aspect_ratio = 1;

      color = graphics_background ;

      }

      : boxed_row {

      label = "Revolution angle: ";

      width = 35;

        :edit_box { // Angle value

        key = "inf" ;

        value = "360";

        edit_width = 3;

        }

        : slider { // Slider bar

        key = "ang";

        width = 27;

        max_value = 360;

        min_value = 1;

        value = 360;

        small_increment = 1;

        big_increment = 10;

        }

      }

    } // End right column

  } // End upper row

  : boxed_radio_row { // Begin boxed radio row

  label = "Predefined forms";

      : radio_button {

      label = "Normal";

      key = "nor";

      value = "1";

      }

      : radio_button {

      label = "Sphere";

      key = "sph";

      value = "0";

      }

      : radio_button {

      label = "Bar";

      key = "bar";

      value = "0";

      }

      : radio_button {

      label = "Tube";

      key = "tub";

      value = "0";

      }

  } // End boxed radio row  

} // End dialog 

//Listing 22.1. Code for the PARAMETRIC dialogue.